practicaexcel

Y y O en Excel: cómo comprobar varias condiciones a la vez

Y y O · en inglés AND / OR · Lógica

Actualizado el

Y y O comprueban varias condiciones a la vez y responden VERDADERO o FALSO. Y da VERDADERO solo si se cumplen todas. O da VERDADERO si se cumple al menos una.

Solas sirven para marcar filas, pero casi siempre las verás dentro de SI, en el lugar de la condición: «si tiene una media de 8 y, además, su familia ingresa menos de 30.000 €…». En el Excel en inglés se llaman AND y OR.

Separador:

Sintaxis

=Y(valor_lógico1; [valor_lógico2]; ...)
valor_lógico1
La primera condición: una comparación como B2>=18, o una celda que contenga VERDADERO o FALSO.
valor_lógico2…
Las demás condiciones, hasta 255 en total.

O se escribe igual y con los mismos argumentos: =O(valor_lógico1; [valor_lógico2]; ...). Para usarlas en un SI, van en el lugar de la prueba lógica: =SI(Y(condición1; condición2); "Sí"; "No").

Ejemplos

Ejemplo 1: Y frente a O, con los mismos datos

Una academia da beca a quien tenga una media de 8 o más y, además, ingresos familiares por debajo de 30.000 €. Para ver la diferencia, en la columna D compruebas los dos requisitos con Y, y en la E con O.

D2fx=Y(B2>=8;C2<30000)
ABCDE
1AlumnoMediaIngresosCon YCon O
2Martina8,624.000VERDADEROVERDADERO
3Tomás9,241.000FALSOVERDADERO
4Florencia7,419.500FALSOVERDADERO
5Gonzalo6,835.000FALSOFALSO

Con Y solo pasa Martina, que cumple las dos cosas. Con O pasan tres, porque les basta con un requisito; solo Gonzalo no cumple ninguno. Para esta beca, la función correcta es Y.

Ejemplo 2: un número entre dos valores

Un gimnasio tiene tarifa joven para los socios de 18 a 25 años, los dos incluidos. La edad tiene que ser mayor o igual que 18 y menor o igual que 25.

D3fx=SI(Y(C3>=18;C3<=25);"Joven";"General")
ABCD
1SocioCiudadEdadTarifa
2PaulaZaragoza16General
3SebastiánSantiago18Joven
4DanielaGuadalajara25Joven
5HugoCórdoba31General

Las dos comparaciones miran la misma celda, una por cada extremo. Sebastián (18) y Daniela (25) entran porque usas >= y <=. Si los extremos no contaran, pondrías > y <.

Ejemplo 3: Y y O juntas

Una tienda online regala el envío en los pedidos de 50 € o más que vayan a Madrid o a Barcelona. La ciudad puede ser cualquiera de las dos (O) y, además, el importe tiene que llegar (Y).

D2fx=SI(Y(O(B2="Madrid";B2="Barcelona");C2>=50);"Gratis";"De pago")
ABCD
1PedidoCiudadImporteEnvío
2P-301Madrid64,50Gratis
3P-302Bilbao120,00De pago
4P-303Barcelona38,00De pago
5P-304Barcelona75,00Gratis

O resuelve la ciudad y Y junta ese resultado con el importe. El pedido de Bilbao no entra aunque pase de 50 €, y el de Barcelona de 38 € tampoco. Fíjate en que B2 se repite en cada comparación: O(B2="Madrid";"Barcelona") no funciona, porque «Barcelona» suelto no es una condición.

Pruébalo aquí

Una librería hace descuento si el cliente es socio o si compra 5 unidades o más. En E3 escribe una fórmula con SI y O que muestre «Sí» si Ignacio tiene descuento y «No» si no lo tiene. El dato de socio está en C3 y las unidades, en D3.

E3fx
ABCDE
1ClienteCiudadSocioUnidades¿Descuento?
2Marcela OrtizValparaísoSí2
3Ignacio VegaSalamancaNo6
4Pilar QuirogaCochabambaNo3
5Andrés LoboGranadaSí8
6Teresa FunesMendozaNo5
Pulsa el botón (o toca la hoja) y escribe la fórmula en E3: se corrige al momento.

Errores frecuentes

Y da siempre FALSO
Pides a una celda dos cosas imposibles a la vez, como =Y(B2="Madrid";B2="Barcelona"). Una celda no puede decir Madrid y Barcelona al mismo tiempo. Si te vale cualquiera de las dos, la función es O.
Un resultado equivocado, sin error
Has escrito «entre» como en matemáticas: =SI(18<=C2<=25;"Joven";"General"). Excel compara primero 18<=C2, obtiene VERDADERO o FALSO, y luego compara eso con 25. El resultado no tiene sentido y no te avisa. Separa los dos límites dentro de Y: Y(C2>=18;C2<=25).
#¿NOMBRE?
Has escrito AND u OR, los nombres en inglés, o un texto sin comillas, como B2=Madrid. En español son Y y O, y los textos van entre comillas: B2="Madrid".
#¡VALOR!
No hay ninguna condición que evaluar. Pasa con =Y(A2:A5) si el rango solo tiene textos o celdas vacías: Y y O se los saltan, y si no queda nada, dan error. Escribe comparaciones completas, como A2="Sí", y no solo la celda.

Trucos

Preguntas frecuentes

¿Qué diferencia hay entre Y y O en Excel?

Y devuelve VERDADERO solo si se cumplen todas las condiciones; O, si se cumple al menos una. Si falla una condición, Y ya da FALSO, mientras que O puede seguir dando VERDADERO.

¿Cómo hago un SI con varias condiciones?

Pon Y u O como primer argumento del SI: =SI(Y(B2>=8;C2<30000);"Beca";"Sin beca"). Y puedes meter una dentro de la otra, como en el ejemplo del envío.

¿Cómo compruebo si un número está entre dos valores?

Con Y y los dos límites: =Y(B2>=100;B2<=500). Usa > y < si los extremos no cuentan.

¿Cómo se dicen AND, OR y XOR en Excel en español?

Y, O y XO. NOT es NO. Si escribes los nombres en inglés en un Excel en español, da #¿NOMBRE?.

Funciones relacionadas