TEXTOANTES y TEXTODESPUES: cómo partir un texto por un separador
TEXTOANTES y TEXTODESPUES · en inglés TEXTBEFORE, TEXTAFTER · Texto
Actualizado el
TEXTOANTES devuelve lo que hay antes de un separador y TEXTODESPUES, lo que hay después. Le das el texto y el carácter por donde cortar (una coma, un espacio, una @) y te devuelve el trozo, sin contar posiciones. Sirven para separar la ciudad del país, el usuario del dominio de un correo o el nombre de los apellidos.
Antes había que combinar IZQUIERDA o EXTRAE con ENCONTRAR. Estas dos funciones lo hacen solas, pero son nuevas: están en Excel 365, Excel 2024 y Excel para la web. En Excel 2021 o anteriores dan #¿NOMBRE?. En inglés se llaman TEXTBEFORE y TEXTAFTER.
Sintaxis
=TEXTOANTES(texto; delimitador; [núm_de_instancia]; …)
texto- El texto que quieres partir, normalmente una celda.
delimitador- Por dónde cortar, entre comillas:
","," ","@". Puede tener varios caracteres, como", "(coma y espacio). No aparece en el resultado. núm_de_instancia- Opcional. Qué aparición del delimitador usar: 1 la primera (si no lo pones), 2 la segunda… Con números negativos cuenta desde el final: -1 es la última.
TEXTODESPUES tiene los mismos argumentos: =TEXTODESPUES(texto; delimitador; [núm_de_instancia]; …). Las dos tienen tres argumentos opcionales más, en este orden. El 4.º, con 1, no distingue mayúsculas (si no lo pones, sí las distingue). El 5.º, con 1, trata el final del texto como un delimitador más. El 6.º es lo que devuelven si no encuentran el delimitador, en lugar de #N/D.
Ejemplos
Ejemplo 1: la ciudad, sin el país
En la lista de oficinas de una empresa, la ciudad y el país van en la misma celda, separados por una coma y un espacio. Quieres la ciudad en su propia columna.
| A | B | |
|---|---|---|
| 1 | Oficina | Ciudad |
| 2 | Medellín, Colombia | Medellín |
| 3 | Valencia, España | Valencia |
| 4 | Rosario, Argentina | Rosario |
| 5 | Guadalajara, México | Guadalajara |
El delimitador es ", ": la coma junto con su espacio. Para el país, la otra mitad, usa =TEXTODESPUES(A2;", "), que da «Colombia». Si cortaras solo por la coma, el país saldría con un espacio delante, « Colombia», y después BUSCARV no lo encontraría en otra tabla.
Ejemplo 2: el nombre de pila, aunque sea compuesto
En España y en buena parte de Latinoamérica la gente tiene dos apellidos, y muchos nombres son compuestos: María José, Juan Carlos. Cortar por el primer espacio no sirve. Lo que sí es fijo es que los dos últimos trozos son los apellidos, así que cuentas los espacios desde el final.
| A | B | |
|---|---|---|
| 1 | Nombre completo | Nombre de pila |
| 2 | María José Fernández Ruiz | María José |
| 3 | Lucía Martín Sanz | Lucía |
| 4 | Juan Carlos Pérez Gómez | Juan Carlos |
| 5 | Ana Belén de la Torre Ríos | Ana Belén de la |
Con -2, TEXTOANTES busca el penúltimo espacio y se queda con lo que hay antes. Los apellidos salen con =TEXTODESPUES(A2;" ";-2): «Fernández Ruiz». Mira la última fila: con un apellido de varias palabras, como «de la Torre», la regla falla. Ninguna fórmula acierta siempre con los nombres, así que revisa a mano los casos raros.
Ejemplo 3: cuando el delimitador no está
En la lista de la compra, algunos productos llevan el formato entre paréntesis y otros no. Quieres el nombre sin el paréntesis. Si TEXTOANTES no encuentra el delimitador da #N/D, así que en la columna C usamos el 6.º argumento: si no hay paréntesis, que devuelva el texto entero.
| A | B | C | |
|---|---|---|---|
| 1 | Producto | Sin el 6.º argumento | Con el 6.º argumento |
| 2 | Aceite de oliva (1 L) | Aceite de oliva | Aceite de oliva |
| 3 | Pan de molde | #N/D | Pan de molde |
| 4 | Leche entera (6 x 1 L) | Leche entera | Leche entera |
| 5 | Huevos camperos (12 uds.) | Huevos camperos | Huevos camperos |
| 6 | Café molido | #N/D | Café molido |
Para llegar al 6.º argumento hay que pasar por el 3.º, el 4.º y el 5.º. Aquí llevan sus valores normales: 1 (la primera aparición), 0 (distingue mayúsculas) y 0 (el final no cuenta como delimitador). El delimitador es " (", con el espacio, para que el nombre no acabe en blanco. Otra forma de hacerlo: con 1 en el 5.º argumento, si no hay paréntesis, corta al final y devuelve el texto entero.
Pruébalo aquí
Cada producto de la columna A lleva su peso detrás de « - ». En B2, escribe una fórmula que devuelva solo el nombre del producto de A2: lo que va antes de « - ».
| A | B | |
|---|---|---|
| 1 | Producto | Nombre |
| 2 | Arroz bomba - 1 kg | |
| 3 | Lentejas pardinas - 500 g | |
| 4 | Harina de maíz - 1 kg | |
| 5 | Frijoles negros - 900 g |
Errores frecuentes
- #N/D
- El delimitador no aparece en el texto, o pides una aparición que no existe: la 3.ª coma de un texto que solo tiene dos. Usa el 6.º argumento para decir qué devolver, como en el ejemplo 3, o rodea la fórmula con SI.ERROR:
=SI.ERROR(TEXTOANTES(A2;"-");A2). - #¡VALOR!
- El núm_de_instancia es 0, o es mayor que el número de caracteres del texto. Usa 1, 2, 3… para contar desde el principio y -1, -2… para contar desde el final.
- #¿NOMBRE?
- Tu Excel no tiene estas funciones (2021 o anterior), o has escrito el nombre en inglés. En versiones antiguas, usa IZQUIERDA con ENCONTRAR:
=IZQUIERDA(A2;ENCONTRAR(", ";A2)-1)hace lo mismo que el ejemplo 1. - Sobra un espacio
- Has cortado por la coma cuando detrás hay un espacio. El espacio se queda en el resultado, y luego las búsquedas fallan. Incluye el espacio en el delimitador:
", ". O limpia el resultado con ESPACIOS.
Trucos
- No distinguen mayúsculas si pones 1 en el 4.º argumento:
=TEXTOANTES(A2;" x ";1;1)corta igual por « x » que por « X ». - Para el trozo de en medio, anídalas:
=TEXTOANTES(TEXTODESPUES(A2;"-");"-")saca «2024» de «MAD-2024-00153». - El usuario de un correo es
=TEXTOANTES(A2;"@"), y el dominio,=TEXTODESPUES(A2;"@"). - Si necesitas todas las partes a la vez, en columnas separadas, Excel 365 tiene DIVIDIRTEXTO.
Preguntas frecuentes
¿Cómo separo nombre y apellidos en Excel?
Si cada persona tiene dos apellidos, =TEXTOANTES(A2;" ";-2) da el nombre (aunque sea compuesto) y =TEXTODESPUES(A2;" ";-2) los apellidos, como en el ejemplo 2. Si solo hay un nombre y un apellido, basta con cortar por el espacio: =TEXTOANTES(A2;" ").
¿Cómo saco el texto que va después de un carácter?
Con TEXTODESPUES: =TEXTODESPUES(A2;"-") devuelve lo que hay detrás del primer guion. Para lo que hay detrás del último, pon -1 como tercer argumento.
¿Por qué me sale #¿NOMBRE? con TEXTOANTES?
Porque tu versión de Excel no la tiene. Está en Excel 365, Excel 2024 y Excel para la web. En versiones anteriores, usa IZQUIERDA con ENCONTRAR para lo de antes, y EXTRAE con ENCONTRAR para lo de después.
¿TEXTOANTES distingue mayúsculas?
Sí, si no le dices lo contrario: cortar por "X" no encuentra una «x» minúscula. Pon 1 en el cuarto argumento para que le dé igual.
¿Se escribe con punto y coma o con coma?
Depende de tu país: con punto y coma en España, Argentina, Colombia o Chile, y con coma en México o Perú. =TEXTOANTES(A2;"@") en España es =TEXTOANTES(A2,"@") en México. Con el selector de arriba ves todos los ejemplos de las dos formas.